AppleScript splitting terminal session doesn't work as expected

I would expect the below applescript to create a grid of 2 rows with 3 columns each, but it doesn't.

tell application "iTerm"
	-- the goal is to create a grid of 6 sessions and let them ssh into 6 different servers
	-- for convenience we refer to the sessions like we do in a spreadsheet (eg. a2 means the first column of the 2nd row)
	local session_a1, session_a2, session_b1, session_b2, session_c1, session_c2
	activate
	-- create a new window
	create window with default profile
	
	set session_a1 to (current session of current window)
	
	tell session_a1
		write text "echo session_a1"
		split horizontally with same profile
		
	end tell
	set session_a2 to (current session of current window)
	
	tell session_a1
		write text "echo session_a1"
		split vertically with same profile
	end tell
	set session_b1 to (current session of current window)
	
	tell session_b1
		write text "echo session_b1"
		split vertically with same profile
	end tell
	set session_c1 to (current session of current window)
	
	
	tell session_c1
		write text "echo session_c1"
	end tell
	
	tell session_a2
		write text "echo session_a2"
		split vertically with same profile
	end tell
	set session_b2 to (current session of current window)
	
	tell session_b2
		write text "echo session_b2"
		split vertically with same profile
	end tell
	set session_c2 to (current session of current window)
	
	
	tell session_c2
		write text "echo session_c2"
	end tell
	activate
	
	
end tell

The references to the sessions are indeed being saved, I can for instance add a few lines at the end to echo to session_b1 and that does appear to be the correct cell:

	tell session_b1
		write text "this does indeed refer to session b1!"
	end tell

FYI, the next nightly build will let you do

set x to (split vertically with same profile)

which might help wrangle the complexity of this script. But I'll put this in the queue to have a look as soon as I'm able (there's a bit of a backlog right now)

Milestone changed to Ship 3.0

This is getting easier now, but we're not there yet :)

tell application "iTerm"
	-- the goal is to create a grid of 6 sessions and let them ssh into 6 different servers
	-- for convenience we refer to the sessions like we do in a spreadsheet (eg. a2 means the first column of the 2nd row)
	local session_a1, session_a2, session_b1, session_b2, session_c1, session_c2
	activate
	-- create a new window
	create window with default profile
	
	
	-- create the first row of three terminal sessions
	set session_a1 to (current session of current window)
	
	tell session_a1
		set session_b1 to (split vertically with same profile)
	end tell
	
	tell session_b1
		set session_c1 to (split vertically with same profile)
	end tell
	
	-- split each session in two horizontally, creating the second row
	tell session_a1
		set session_a2 to (split horizontally with same profile)
	end tell
	
	tell session_b1
		set session_b2 to (split horizontally with same profile)
	end tell
	
	tell session_c1
		set session_c2 to (split horizontally with same profile)
	end tell
	
	-- echo to each session to see what happened	
	tell session_a1
		write text "echo session_a1"
	end tell
	tell session_a2
		write text "echo session_a2"
	end tell
	tell session_b1
		write text "echo session_b1"
	end tell
	tell session_b2
		write text "echo session_b2"
	end tell
	tell session_c1
		write text "echo session_c1"
	end tell
	tell session_c2
		write text "echo session_c2"
	end tell
	
	
	
end tell

Fixed in commit c9f74847, try the next nightly build.

Status changed to closed

@walterheck What are you doing with this btw?

I just built something that might be similar: https://github.com/TomAnthony/itermocil

@TomAnthony I have a number of clusters that I take care of, usually 5 or 6 machines. It involves logging into one of the machines first through ssh, then to the others (they use the ssh session of the first connection). itermocil looks interesting, I'll try it soon.

@gnachman by the way it works perfectly now, at least for the example I posted. Thanks a ton for the quick fixes!